Commit

2026-02-28 19:41:14 +01:00
parent 0c81f68a63
commit 5f34d32807
53 changed files with 1303 additions and 1386 deletions
--- a/modules/apps/pim.nix
+++ b/modules/apps/pim.nix
@@ -0,0 +1,86 @@
+{ den, ... }:
+{
+  lux.pim = den.lib.parametric {
+    includes = [
+      (
+        { user, ... }:
+        {
+          homeManager =
+            { config, ... }:
+            let
+              calendarsPath = "${config.xdg.dataHome}/calendars";
+            in
+            {
+              programs.pimsync.enable = true;
+              services.pimsync.enable = true;
+
+              programs.khal = {
+                # FIXME: Temporarily disabled because of bug in nixpkgs-unstable (27-02-26)
+                enable = false;
+                locale = {
+                  timeformat = "%H:%M";
+                  dateformat = "$m-$d";
+                };
+              };
+
+              programs.todoman = {
+                enable = true;
+                glob = "*/*";
+                extraConfig = ''
+                  date_format = "%Y-%m-%d"
+                  time_format = "%H:%M"
+                  default_list = "personal"
+                  default_due = 0
+                  default_command = "list --sort priority,due"
+                  humanize = True
+                '';
+              };
+
+              accounts.calendar = {
+                basePath = calendarsPath;
+                accounts = {
+                  "radicale" = {
+                    primary = true;
+                    primaryCollection = "personal";
+
+                    local = {
+                      type = "filesystem";
+                      fileExt = ".ics";
+                    };
+
+                    remote = {
+                      url = "https://radicale.${user.serverDomain}/";
+                      type = "caldav";
+                      userName = user.name;
+                      passwordCommand = [
+                        "rbw"
+                        "get"
+                        "Radicale"
+                      ];
+                    };
+
+                    pimsync = {
+                      enable = true;
+                      extraPairDirectives = [
+                        {
+                          name = "collections";
+                          params = [ "from b" ];
+                        }
+                      ];
+                    };
+
+                    khal = {
+                      enable = true;
+                      type = "discover";
+                      color = "light blue";
+                    };
+                  };
+                };
+              };
+
+            };
+        }
+      )
+    ];
+  };
+}