refactor: move from den based to flake-parts based

2026-04-21 00:59:54 +02:00
parent d2ab961c48
commit 5bed1336c0
71 changed files with 1832 additions and 2472 deletions
@@ -0,0 +1,85 @@
+{ config, ... }:
+let
+  homeModules = config.flake.modules.homeManager;
+
+  realName = "Jelle Spreeuwenberg";
+
+  accounts = {
+    kiri = {
+      homeDirectory = "/home/kiri";
+      gitEmail = "mail@jelles.net";
+      vaultEmail = "mail@jelles.net";
+      extraHomeImports = with homeModules; [ syncthing ];
+    };
+
+    ergon = {
+      homeDirectory = "/home/ergon";
+      gitEmail = "jelle.spreeuwenberg@yookr.org";
+      vaultEmail = "jelle.spreeuwenberg@yookr.org";
+      extraHomeImports = with homeModules; [ nix ];
+    };
+  };
+
+  mkUser =
+    { accountName }:
+    {
+      config,
+      pkgs,
+      ...
+    }:
+    let
+      account = accounts.${accountName};
+    in
+    {
+      sops.secrets."hashed-password-${accountName}".neededForUsers = true;
+
+      programs.zsh.enable = true;
+
+      users.users.${accountName} = {
+        name = accountName;
+        home = account.homeDirectory;
+        hashedPasswordFile = config.sops.secrets."hashed-password-${accountName}".path;
+        isNormalUser = true;
+        shell = pkgs.zsh;
+        extraGroups = [
+          "wheel"
+          "networkmanager"
+        ];
+      };
+
+      home-manager.users.${accountName} = {
+        home = {
+          username = accountName;
+          homeDirectory = account.homeDirectory;
+          stateVersion = "24.05";
+        };
+
+        imports =
+          with homeModules;
+          [
+            terminal
+            shell
+            neovim
+            sshClient
+            sopsAdmin
+            git
+            devTools
+            podman
+            gemini
+          ]
+          ++ account.extraHomeImports;
+
+        programs.git.settings.user = {
+          name = realName;
+          email = account.gitEmail;
+        };
+
+        programs.rbw.settings.email = account.vaultEmail;
+      };
+    };
+in
+{
+  flake.modules.nixos.kiri = mkUser { accountName = "kiri"; };
+
+  flake.modules.nixos.ergon = mkUser { accountName = "ergon"; };
+}