{
  config,
  lib,
  ...
}:
let
  repo = config.repo;
  repoHelpers = repo.helpers;

  mkNoctaliaSettings =
    {
      lib,
      terminalPackage,
    }:
    import ./_noctalia-config.nix {
      inherit
        lib
        terminalPackage
        ;
    };

  mkBaseSettings =
    {
      lib,
      pkgs,
    }:
    let
      terminalPackage = repoHelpers.resolvePackagePath {
        inherit pkgs;
        path = repo.desktop.terminal.packagePath;
      };
    in
    if terminalPackage == null then
      { }
    else
      mkNoctaliaSettings {
        inherit lib terminalPackage;
      };

  mkPortableSettings =
    baseSettings:
    lib.recursiveUpdate baseSettings {
      bar.widgets.right = lib.concatMap (
        widget:
        if widget.id == "ControlCenter" then
          [
            {
              id = "Network";
            }
            {
              id = "Battery";
              showPowerProfiles = true;
              displayMode = "graphic";
            }
            widget
          ]
        else
          [ widget ]
      ) baseSettings.bar.widgets.right;
    };
in
{
  flake.modules.homeManager.noctalia =
    {
      inputs,
      lib,
      pkgs,
      ...
    }:
    let
      baseSettings = mkBaseSettings {
        inherit lib pkgs;
      };
    in
    {
      imports = [ inputs.noctalia.homeModules.default ];

      programs.noctalia-shell = {
        enable = true;
        package = lib.mkForce (
          inputs.noctalia.packages.${pkgs.stdenv.hostPlatform.system}.default.override {
            calendarSupport = true;
          }
        );

        settings = baseSettings;
      };
    };

  flake.modules.homeManager.noctalia-portable =
    {
      inputs,
      lib,
      pkgs,
      ...
    }:
    let
      baseSettings = mkBaseSettings {
        inherit lib pkgs;
      };
    in
    {
      imports = [ inputs.noctalia.homeModules.default ];

      programs.noctalia-shell = {
        enable = true;
        package = lib.mkForce (
          inputs.noctalia.packages.${pkgs.stdenv.hostPlatform.system}.default.override {
            calendarSupport = true;
          }
        );
        settings = if baseSettings == { } then { } else mkPortableSettings baseSettings;
      };
    };
}