{
  flake.modules.nixos.theme =
    {
      pkgs,
      ...
    }:
    let
      cursorTheme = {
        name = "phinger-cursors-light";
        package = pkgs.phinger-cursors;
        size = 24;
      };
    in
    {
      environment.systemPackages = [ cursorTheme.package ];

      services.displayManager.sddm.settings = {
        Theme = {
          CursorTheme = cursorTheme.name;
          CursorSize = cursorTheme.size;
        };
      };
    };

  flake.modules.homeManager.theme =
    { config, pkgs, ... }:
    let
      cursorTheme = {
        name = "phinger-cursors-light";
        package = pkgs.phinger-cursors;
        size = 24;
      };

      kanagawaThemeSrc = pkgs.fetchFromGitHub {
        owner = "Fausto-Korpsvart";
        repo = "Kanagawa-GKT-Theme";
        rev = "55ca4ba249eba21f861b9866b71ab41bb8930318";
        hash = "sha256-UdMoMx2DoovcxSp/zBZ3PRv/Qpj+prd0uPm1gmdak2E=";
      };

      kanagawaOverride = {
        version = "unstable-2025-10-23";
        src = kanagawaThemeSrc;
      };
    in
    {
      home.pointerCursor = {
        inherit (cursorTheme)
          name
          package
          size
          ;
        gtk.enable = true;
      };

      gtk = {
        enable = true;
        gtk3.bookmarks = [
          "sftp://orion Orion VPS"
        ];
        theme = {
          name = "Kanagawa-BL-LB";
          package = pkgs.kanagawa-gtk-theme.overrideAttrs (_: kanagawaOverride);
        };
        gtk4.theme = {
          inherit (config.gtk.theme) name package;
        };
        iconTheme = {
          name = "Kanagawa";
          package = pkgs.kanagawa-icon-theme.overrideAttrs (_: kanagawaOverride);
        };
      };

      qt = {
        enable = true;
        platformTheme.name = "gtk3";
      };
    };
}