{
  config,
  lib,
  ...
}:
let
  homeModules = config.flake.modules.homeManager;
  metaLib = config.meta.lib;
  mkPortableSettings =
    baseSettings:
    lib.recursiveUpdate baseSettings {
      bar.widgets.right = lib.concatMap (
        widget:
        if widget.id == "ControlCenter" then
          [
            {
              id = "Network";
            }
            {
              id = "Battery";
              showPowerProfiles = true;
              displayMode = "graphic";
            }
            widget
          ]
        else
          [ widget ]
      ) baseSettings.bar.widgets.right;
    };
in
{
  flake.modules.homeManager.noctalia =
    {
      inputs,
      config,
      lib,
      pkgs,
      ...
    }:
    let
      terminal = metaLib.resolveUserTerminal {
        inherit pkgs;
        user = config.meta.user;
      };
      baseSettings =
        if terminal.hasMainProgram then
          import ./_noctalia-config.nix {
            inherit
              lib
              ;
            terminalPackage = terminal.package;
          }
        else
          { };
    in
    {
      imports = [ inputs.noctalia.homeModules.default ];

      assertions = metaLib.mkTerminalAssertions {
        inherit terminal;
        user = config.meta.user;
      };

      programs.noctalia-shell = {
        enable = true;
        package = lib.mkForce (
          inputs.noctalia.packages.${pkgs.stdenv.hostPlatform.system}.default.override {
            calendarSupport = true;
          }
        );

        settings = baseSettings;
      };
    };

  flake.modules.homeManager.noctalia-portable =
    {
      config,
      lib,
      pkgs,
      ...
    }:
    let
      terminal = metaLib.resolveUserTerminal {
        inherit pkgs;
        user = config.meta.user;
      };
      baseSettings =
        if terminal.hasMainProgram then
          import ./_noctalia-config.nix {
            inherit
              lib
              ;
            terminalPackage = terminal.package;
          }
        else
          { };
    in
    {
      imports = [ homeModules.noctalia ];
      programs.noctalia-shell.settings = lib.mkForce (
        if terminal.hasMainProgram then mkPortableSettings baseSettings else { }
      );
    };
}