{ config, ... }:
let
  repo = config.repo;
in
{
  flake.modules.homeManager.desktop-defaults =
    { config, pkgs, ... }:
    let
      browserPackage = pkgs.${repo.desktop.browser.packageAttr};
      fileManagerPackage = pkgs.${repo.desktop.fileManager.packageAttr};
      homeDir = config.home.homeDirectory;
      localDir = "${homeDir}/.local";
      mediaDir = "${homeDir}/media";
    in
    {
      home.preferXdgDirectories = true;
      home.sessionVariables.BROWSER = repo.desktop.browser.command;

      home.packages =
        with pkgs;
        [
          postman
          spotify
          calcure
          planify
          unzip
          gimp
          dbeaver-bin
        ]
        ++ [
          browserPackage
          fileManagerPackage
        ];

      programs.imv.enable = true;
      programs.sioyek.enable = true;

      xdg = {
        enable = true;

        cacheHome = "${localDir}/cache";
        configHome = "${homeDir}/.config";
        dataHome = "${localDir}/share";
        stateHome = "${localDir}/state";

        userDirs = {
          enable = true;
          createDirectories = true;
          setSessionVariables = true;

          download = "${homeDir}/downloads";
          documents = "${homeDir}/documents";
          projects = "${homeDir}/dev";
          music = "${mediaDir}/music";
          pictures = "${mediaDir}/images";
          videos = "${mediaDir}/videos";
          desktop = "${localDir}/desktop";
          publicShare = "${localDir}/public";
          templates = "${localDir}/templates";
        };

        mimeApps = {
          enable = true;
          defaultApplicationPackages =
            with pkgs;
            [
              sioyek
              imv
              neovim
            ]
            ++ [
              browserPackage
              fileManagerPackage
            ];
        };
      };
    };
}